Interne Tabellen (ABAP)
Interne Tabellen sind Tabellen, die im Hauptspeicher gehalten werden. Im Gegensatz dazu werden Datenbanktabellen im Datenbanksystem abgelegt.
Strukturtyp definieren
Für die nachfolgenden Beispiele sei die folgende Struktur gegeben. Diese könnte auch im Dictionary definiert sein.
" Struktur für Buch
TYPES: BEGIN OF lst_buch,
buch_titel type string,
anz_seiten type int4,
END OF lst_buch.
Aufbau von internen Tabellen
Interne Tabellen benötigen einen Tabellentyp. Ein Tabellentyp kann per Code oder im Dictionary definiert werden. Er definiert:
- Zeilentyp, z. B. ein Strukturtyp
- Tabellenart, z. B. STANDARD
- Schlüsseldefinition: z. B. WITH NON_UNIQUE DEFAULT KEY
Tabellenarten
| Typ | ANY* | ||
|---|---|---|---|
| Generisch | INDEX TABLE* | Hashed Table | |
| Tabellenart | STANDARD TABLE | SORTED TABLE | HASHED TABLE |
| Indexzugriff | Ja | Ja | Nein |
| Schlüsselzugriff | Ja | Ja | Ja |
| Schlüsseleindeutigkeit | NON-UNIQUE | UNIQUE oder NON-UNIQUE | UNIQUE |
| Bemerkung | Kann und muss im
Schlüssel keine eindeutigen Werte enthalten. |
Kann und muss im
Schlüssel eindeutige Werte enthalten. |
Schlüssel muss
eindeutige Werte |
*) ANY und INDEX TABLE können als Typisierung für Schnittstellen von Methode, Funktionsbausteinen etc. verwendet werden.
Beispiel für explizite Definition:
" Tabellentyp für sortierte Tabelle
TYPES: ltt_buchregal_sortiert TYPE SORTED TABLE OF lst_buch
WITH NON-UNIQUE DEFAULT KEY.
" Tabellentyp für hashed Tabelle
TYPES: ltt_buchregal_hashed TYPE HASHED TABLE OF lst_buch
WITH UNIQUE DEFAULT KEY.
Schlüsseldefinition
Der Standardschlüssel DEFAULT KEY umfasst alle nicht numerischen Felder des Strukturtyps.
Beispiel für explizite Definition:
" Tabellentyp für sortierte Tabelle mit Schlüsselfeld anz_seiten
TYPES: ltt_buchregal_sortiert TYPE SORTED TABLE OF lst_buch
WITH NON-UNIQUE KEY anz_seiten.
Wichtig sind folgende Einschänkungen zur Schlüsseleindeutigkeit:
| Tabellenart | Schlüsseleindeutigkeit | Beschreibung |
|---|---|---|
| STANDARD | NON-UNIQUE | Kann mehrere Einträge mit identischen Schlüsselwerten enthalten |
| SORTED | UNIQUE und NON-UNIQUE | Eindeutigkeit der Schlüsselwerte ist optional |
| HASHED | UNIQUE | Einträge müssen eindeutige Schlüsselwerte tragen |
Erstellen von internen Tabellen
Beispiel für implizite Definition einer internen Tabells aus einer Struktur:
DATA: lt_buchregal TYPE TABLE OF lst_buch
Beispiele für explizite Definition eines Tabellentyps und anschließende definition einer internen Tabelle. Der Tabellentyp könnte auch im Dictionary definiert werden:
" Tabellentyp für Standard-Tabelle
TYPES: ltt_buchregal TYPE STANDARD TABLE OF lst_buch " Definition lst_buch siehe oben
WITH NON-UNIQUE DEFAULT KEY.
DATA: lt_buchregal TYPE ltt_buchregal.
Für die Bearbeitung einer internen Tabelle wird eine Arbeitsstruktur, manchmal auch als Workarea bezeichnet, benötigt.
Eine Arbeitsstruktur kann mittels LIKE LINE OF auf Basis einer internen Tabelle erstellt werden:
" Definition einer internen Tabelle auf Basis eines Tabellentyps
DATA: lt_biblio TYPE ltt_biblio.
" Erstellung einer passenden Struktur
DATA: ls_biblio LIKE LINE OF lt_biblio.
Alternativ kann eine Struktur auf Basis einer Datenbanktabelle (transparenten Tabelle) mit TYPE erstellt werden:
" Erstellen einer Struktur auf Basis der Datenbanktabelle zbiblio
DATA: ls_biblio TYPE zbiblio.
" Allgemeine Formulierung
DATA: <wa> TYPE <dbtab>
Eine interne Tabelle kann mit TYPE TABLE OF auf Basis einer Datenbanktabelle erstellt werden:
" Interne Tabelle auf Basis transp. Tabelle
DATA: lt_cust TYPE TABLE OF zcust.
Andere Möglichkeit eine interne Tabelle auf Basis einer Datenbanktabelle anzulegen ist LIKE:
" Gegeben ist, dass /BIC/AZNWVKDAT00 eine transparente Tabelle eines DSOs ist
DATA: lt_data LIKE TABLE OF /BIC/AZNWVKDAT00.
Lesen von Daten
Gesamte interne Tabelle lesen
Früher: Interne Tabellen wurden mit Kopfzeilen angelegt (Stichwort ABAP-Anweisung OCCURS).
Das heißt, die Kopfzeile ist die Arbeitsstruktur in die die Daten der Tabelle geschrieben werden.
Diese Arbeitsstruktur ist namensgleich mit dem Tabellenkorpus. Damit war eine verkürzte Notation möglich:
" Verkürzte Notation
LOOP AT <itab>.
" Code
ENDLOOP.
Empfehlung heute: Interne Tabellen ohne Kopfzeilen anlegen. Damit ist der Weg für optimierten Zugriff auf die Tabelleninhalte frei.
" Lange Notation
LOOP AT <itab> INTO <wa>.
" Code
ENDLOOP.
Einzelne Datensätze lesen
Einzelne Datensätze aus interner Tabelle in eine Arbeitsstruktur lesen.
READ TABLE <itab> INTO <wa> WITH [TABLE] KEY <s1> = <f1>.
Für mehrere Sätze besser einen LOOP über die interne Tabelle erstellen.
Einfügen / Schreiben von Daten
Datensätze können in interne Tabellen mit INSERT oder APPEND geschrieben werden.
" Anhängen von Daten am Ende der internen Tabelle
APPEND <wa> TO <itab>
Bei SORTED- oder HASHED-Tabellen kann auch INSERT verwendet werden:
INSERT <wa> INTO TABLE <itab>
Abhängig von Tabellenart passiert bei INSERT jedoch etwas anderes:
| Tabellenart | Erläuterung |
|---|---|
| STANDARD | Datensatz wird angehängt |
| SORTED | Datensatz wird laut Schlüsselfeldern sortiert eingefügt |
| HASHED | Datensatz wird laut schlüssel eingefügt, jedoch nicht sortiert |
Kopieren
Kopieren von Inhalten einer internen Tabelle in eine andere interne Tabelle, wobei beide einige unterschiedliche Felder haben können:
LOOP AT lt_vkdat INTO ls_vkdat.
" MOVE-CORRESPONDING ermöglicht es Feldinhalte zu kopieren, wenn die Strukturen einzelne abweichende Felder haben
MOVE-CORRESPONDING ls_vkdat TO ls_vkdat_res.
ls_vkdat_res-p10_custno = ls_vkdat-customer.
ls_vkdat_res-amount = ls_vkdat-amount + 2000.
APPEND ls_vkdat_res TO lt_vkdat_res.
ENDLOOP.
Sortieren
Interne Tabellen können sortiert werden:
SORT <itab> BY <spalte> [ASCENDING|DESCENDING]
Dies passiert auf dem Applikationsserver.
Leeren von internen Tabellen
CLEAR initialisiert interne Tabellen ohne den Speicher frei zu geben:
" Leeren der Tabelle und der Arbeitsstruktur
CLEAR lt_itab.
CLEAR ls_itab.
" Optional in einem Kettensatz
CLEAR: lt_itab, ls_itab.
FREE gibt den von der Tabelle beanspruchten Speicher frei:
FREE: lt_itab, ls_itab.
Wenn die Tabelle nach einem FREE erneut angesprochen wird, wird der Speicher wieder reserviert, was Performance kostet.
Übergabe an Funktionsbausteine
Funktionsbausteine benötigen für das entgegen Nehmen von internen Tabellen einen Tabellentyp.
Dieser wird im Dictionary definiert.
Wenn eine interne Tabelle auf Basis einer Datenbanktabelle erstellt wurde, muss ein entsprechender Tabellentyp im Dictionary definiert werden, der als Zeilentyp die Datenbanktabelle entählt.
Ungetestet: Alternativ kann der Parameter im Funktionsbaustein den TYPE "like dbtab" erhalten. Dieses Vorgehen ist jedoch ungetestet.
